MASM 布教のために書いた【MASM談義】シリーズです。
　x86 アセンブラプログラミングに興味がある方はどうぞ。


-----
【MASM談義】 0. 導入編

　MASM はメジャーバージョンが 5 から 6 にアップした際、かなり大きな変更が加えられ、MASM5 以前のコードとの互換性は一部失われました。（互換性を保つためのスイッチが用意されています）
　MASM6 は構造化プログラミングに対応したマクロアセンブラです。

　全く需要はないと思いますが、これから簡単に MASM6 についてあらまし的な解説をしていきたいと思います。

　なお、最新の MASM のリファレンスは MSDN ライブラリに収録されています。
　MASM アセンブラ本体は、Visual Studio をインストールすると bin フォルダに ml.exe が入っていると思いますが、それです。(今は MASM7 あたりのバージョンじゃないかと思います)
（※.NET 2005 から ml64 はバージョン8になっている様子）

　因みに個人的に一番使い勝手の良かったマニュアルは、今となっては大昔に購入した MASM6.11（英語版）に付属していたマニュアルですが、多分どこにも売ってないと思います。
（そもそも日本語版の MASM6 を見たことも聞いたこともないので、それが日本語の参考書では MASM5 止まりになっている（全く無いわけではないようですが）大きな理由のような気がします）

　ここでは MASM6 の特徴的な部分を中心に例文を交えながら記述していきます。
　C 言語や x86 ニーモニックなどの基礎知識を前提にしています。
　各構文の細かい説明は MSDN ライブラリや MASM の参考書などを参照してください。

1. x86あらまし
2. 型と構造体
3. 定数、テキストマクロ
4. 条件と繰り返しマクロ
5. マクロ
6. マクロ関数
7. フロー制御ディレクティブ
8. 関数
補遺

　3〜6 はマクロについて、2, 7, 8 は構造化プログラミングについて紹介します。



-----
【MASM談義】 1. x86あらまし

【歴史】

　x86 系と呼ばれる命令セットは、古くは8ビットCPUである80系（8080）にまでさかのぼることが出来ます。
　8ビットCPUである 8080 と、16ビットCPUである 8086 はバイナリレベルでの互換性はありませんが、命令セットは受け継いでおり（ニーモニックは変更されましたが）、8086 に対応したアセンブラで 8080 用のニーモニックコードをそのままアセンブルすることが出来ました。
　32ビット化されたときにずいぶんアーキテクチャが変更されたとはいえ、8086 以降バイナリレベルでの互換性が保たれているため、汎用レジスタが8本しかないことや、8ビットの変則的なパーシャルレジスタ（ah, bh, ch, dh）など、未だに8ビット時代の名残を見ることが出来ます。


【ニーモニック】

　ニーモニックは一般的に次の形式をとります。

    （命令） （出力オペランド）, （入力オペランド）

　x86 ニーモニックには主に以下のオペランド形式があります。

    imm
    reg/mem
    reg/mem, reg
    reg, mem
    reg/mem, imm
    reg, reg/mem, imm8

　reg はレジスタ、reg/mem はレジスタまたはメモリオペランドです。
　imm は整数、imm8 は8ビットの整数です。


【メモリオペランド】

　メモリオペランドには以下の形式があります。（32ビットモード）

    [disp32]
    [base]
    [base + disp]
    [index * scale + disp32]
    [base + index * scale]
    [base + index * scale + disp]

　disp は8ビットまたは32ビット整数で、8ビットの場合には符号ビットが拡張されます。disp32 は32ビット整数です。
　base 及び index は任意の汎用レジスタ（eax,ebx,ecx,edx,esi,edi,ebp,esp、但し index に esp は不可）です。
　scale は 1, 2, 4, 8 のいずれかとなります。

　MASM ではメモリをあらわすのに [expr] の形式を取りますが、[expr][expr] のようにオフセットアドレスを記述することが可能で、これは [expr+expr] と同じ意味になります。
　変数名シンボルを使う場合には [ ] 記号は使わず、直接変数名を記述します。
　構造体のメンバへアクセスする場合にも [expr].member[expr] のように任意にオフセットを記述できますが、上記形式の通り、レジスタ要素は2つまでしか使用できないことに注意が必要です。



-----
【MASM談義】 2. 型と構造体

【基本データ型】

　アセンブラで扱う基本的なデータには主に以下の型があります。

     BYTE  SBYTE  WORD  SWORD  DWORD  SDWORD  QWORD
     REAL4  REAL8  REAL10

　SBYTE, SWORD, SDWORD はそれぞれ BYTE, WORD, DWORD に対する符号付きの表現形式（符号付き整数型）を表します。
　REAL4, REAL8, REAL10 は浮動小数点形式です。


【構造体】

　C 言語と同様に構造体や共用体を定義できます。

    DATA    STRUCT
        a    DWORD    ?
        b    WORD     ?
        d    WORD     ?
    DATA    ENDS

　これは C 言語の

    struct    DATA
    {
        unsigned long int     a ;
        unsigned short int    b ;
        unsigned short int    d ;
    } ;

と同じです。
　また同様に入れ子の構造体や共用体を定義できます。

    DATA    STRUCT
        UNION    a
            a1    DWORD    ?
            a2    REAL4    ?
        ENDS
        STRUCT    b
            b1    WORD    ?
            b2    WORD    ?
        ENDS
        STRUCT
            d    WORD    ?
            e    WORD    ?
        ENDS
    DATA    ENDS

　これは C 言語の

    struct    DATA
    {
        union
        {
            unsigned long int    a1 ;
            float                a2 ;
        }    a ;
        struct
        {
            unsigned short int    b1 ;
            unsigned short int    b2 ;
        }    b ;
        struct
        {
            unsigned short int    d ;
            unsigned short int    e ;
        } ;
    } ;

と同じです。


【型の定義とポインタ】

　C 言語と同様に TYPEDEF によって型を定義することが出来ます。

    PBYTE    TYPEDEF    PTR BYTE

　これは C 言語の

    typedef unsigned char *    PBYTE ;

と同じです。（型の表現において PTR はポインタを表します）

　また関数ポインタの型を表現することも出来ます。

    TypeFunc    TYPEDEF    PROTO    :PTR SDWORD, :SDWORD
    PtrFunc     TYPEDEF    PTR TypeFunc

　これは C 言語の

    typedef int (*PtrFunc)( int *, int ) ;

と同じです。（返り値の型はアセンブリ上では表現されません）

　ポインタを介して構造体のメンバにアクセスする場合、

    movsx    eax, (DATA_TYPE PTR [ecx]).member

のように記述しますが、ASSUME 文を使って

    ASSUME    ecx:PTR DATA_TYPE
    movsx     eax, [ecx].member
    ASSUME    ecx:NOTHING

と記述することも出来ます。



-----
【MASM談義】 3. 定数、テキストマクロ

【定数式】

　アセンブラで記述される数式は、（メモリアドレスを計算するもの以外は）大抵定数を表す式です。
　例えば、

    shl eax, 1+2

の「1+2」は「3」という即値となります。
　MASM の定数式で使える演算子には

    + - * / MOD AND NOT OR SHL SHR XOR
    EQ GE GT LE LT NE OFFSET SIZEOF

等があります。
　命令と演算子を混同しないようにしましょう。

（例）    test eax, (1 SHL 16)    ; 第16ビットをテスト

　MASM で扱う式には他に、リテラル文字列を生成するものや、アドレス式、ランタイム条件式（後述）と言ったものがあります。


【リテラル文字列】

　リテラル文字列とは、マクロの中では文字列のように扱われ、文の中ではリテラルとなるアイテムです。
　リテラル文字列は

    <text>

のように <> 演算子で囲んで記述します。
　! 記号は文字リテラルを生成する演算子で、

    <a !> b>

は、「a > b」という文字列のリテラルを生成します。

　式の評価値をリテラル文字列に変換するには % 演算子を用います。
　例えば、%(16*3) は <48> と同じ意味になります。


【定数とテキストマクロ】

　シンボルに定数や文字列を割り当てる機能はアセンブラの古典的な機能の一つです。
　MASM6 では、明示的に定数とテキストマクロを使い分けることができます。
　例えば、

    @NUMBER EQU     123
    MOVE    TEXTEQU <mov>

と定義しておいて、

    MOVE eax, @NUMBER * 2

と記述すると

    mov eax, 246

のように解釈されます。

　また、= 記号でも定数を定義できますが、これは再定義可能なので変数のように扱えます。
　例えば、

    @NUMBER = 123
    mov eax, @NUMBER
    @NUMBER = @NUMBER * 2
    mov eax, @NUMBER

は、

    mov eax, 123
    mov eax, 246

と解釈されます。



-----
【MASM談義】 4. 条件と繰り返しマクロ

【条件アセンブル】

　MASM の IF 文は C 言語の #if ディレクティブと同様の条件ディレクティブです。
　IF, ELSEIF, ELSE, ENDIF などを使用します。

    _DEBUG   EQU  1
    IF _DEBUG
       mov   eax, 1
    ELSE
       mov   eax, 0
    ENDIF

　このコードは

       mov   eax, 1

が選択されます。


【反復展開マクロ】

　FOR, FORC, REPEAT, WHILE 文は ENDM までの区間を繰り返し展開するマクロです。（もちろん入れ子にすることも可能です）
　例えば、REPEAT 文は指定回数ブロックを展開します。

    @INDEX = 1
    REPEAT 3
        DWORD    @INDEX * 16
        @INDEX = @INDEX + 1
    ENDM

は

    DWORD    1 * 16
    DWORD    2 * 16
    DWORD    3 * 16

のように展開されます。（@INDEX の値が展開されるごとに変化することに注意してください）

　FOR 文では引数リストを指定します。

    FOR @NAME, <data1, data2, data3>
        add    eax, @NAME
    ENDM

これは

    add eax, data1
    add eax, data2
    add eax, data3

のように展開されます。

　また、マクロブロックを途中で終了したり、展開する位置を変更したい場合には、EXITM や GOTO 文を使用することも出来ます。


-----
【MASM談義】 5. マクロ

　マクロは C++ のインライン関数に似ています。
　例えば

    muladd  MACRO   dst, src1, src2
          imul  dst, src1
          add   dst, src2
       ENDM

という記述は、3つの引数を持った muladd という名前のマクロを定義しています。
　引数はリテラル文字列として渡されます。
　例えば

    muladd   eax, data1, data2

という記述は

    imul  eax, data1
    add   eax, data2

と展開されます。
　各引数は以下のように明示的に <> 記号で囲んで渡すことも出来ます。
（引数に , 記号を含んでいる文字列を渡す場合などには明示することが必要です）

    muladd   <eax>, <data1>, <data2>

　引数を定義する際、:REQ や :VARARG, := で引数の省略不可や可変長引数リスト、省略したときのデフォルトリテラルを指定することも出来ます。
　また、LOCAL 文で MACRO ブロック内で使用するローカルなシンボルを宣言することで、グローバルなシンボルを汚染しないで記述できます。

    sum    MACRO    reg_name:REQ, var_expr:REQ, count:REQ, step:=<4>
        LOCAL    @INDEX
            mov    reg_name, var_expr[0]
            @INDEX = 1
            WHILE @INDEX LT (count)
                add    reg_name, var_expr[@INDEX * (step)]
                @INDEX = @INDEX + 1
            ENDM
        ENDM

    sum    eax, data, 3

この記述は

    mov    eax, data[0]
    add    eax, data[4]
    add    eax, data[8]

のように展開されます。



-----
【MASM談義】 6. マクロ関数

　マクロ関数は値（リテラル文字列）を返すマクロです。
　これは C 言語の #define ディレクティブに似ています。

　基本的に通常のマクロと同じ記述を用いますが、マクロが返す値は EXITM で記述します。

　例えば、階乗を計算するマクロ関数は

    factorial    MACRO    num:REQ
            IF    (num) LE 1
                EXITM    <1>
            ENDIF
            EXITM    %(factorial( %((num) - 1) ) * (num))
        ENDM

と記述することが出来、例えば

    mov eax, factorial(4)

は

    mov eax, 24

と同じ意味です。

　以下のマクロ関数はシステムで定義されています。

    @CatStr  @InStr  @SizeStr  @SubStr

　例えば

    REG_NAME_0    TEXTEQU    <eax>
    REG_NAME_1    TEXTEQU    <ebx>
    REG_NAME_2    TEXTEQU    <ecx>
    REG_NAME_3    TEXTEQU    <edx>

    @reg    MACRO    reg_num:REQ
            IF    ((reg_num) LT 0) OR ((reg_num) GT 3)
                .ERR
            ENDIF
            EXITM    @CatStr( <REG_NAME_>, %(reg_num) )
        ENDM

    mov    @reg(0), @reg(1)

は

    mov    eax, ebx

と展開されます。
（@CatStr マクロは、二つのリテラル文字列を結合します）



-----
【MASM談義】 7. フロー制御ディレクティブ

【条件分岐】

　.IF 〜 .ELSEIF 〜 .ELSE 〜 .ENDIF ディレクティブはランタイムで実行ブロックを選択します。
　.IF , .ELSEIF 文にはランタイム条件式を記述します。
　ランタイム条件式には以下の演算子を使用できます。

    !=  <  <=  ==  >  >=  !  &  || &&

　これらの意味は C 言語のそれと同様です。
　定数式における NE, LT, LE, EQ, GT, GE, NOT, AND, OR 演算子とは区別されることに注意してください。
（定数式はオペランドの即値になりますが、ランタイム条件式は対応ニーモニックを生成し、ランタイムに評価されます）
　また、値の大小を比較する際には、データの型（符号の有無）に注意してください。

　これらのほか、以下の要素を指定できます。

    CARRY?  OVERFLOW?  PARITY?  SIGN?  ZERO?

　これらはフラグレジスタのステータスを意味します。
　例えば

    sub    eax, ecx
    .IF    ZERO? && (edx == eax)

のように記述し、この場合の意味は

    sub    eax, ecx
    .IF    (eax == 0) && (edx == eax)

と同様です。（但し cmp 命令の副作用に注意してください）
　因みに、& 演算子では test 命令が、(reg == 0) 形式は or reg, reg 命令が生成されます。（定数の場合には jmp 命令が生成されます）
　また、入れ子になった制御ブロックで不要な（無駄な）ジャンプ命令は生成されません（結合されます）。

    .IF    ZERO?
        .IF    eax != 1
            dec    eax
        .ENDIF
    .ELSE
        xor    eax, eax
    .ENDIF

　このような記述では、以下のようなコードが生成されます。
（eax != 1 の条件に一致しない場合、dec eax の次ではなく、外側の .ENDIF までジャンプします）

        jnz    LABEL1
        cmp    eax, 1
        jz     LABEL2
        dec    eax
        jmp    LABEL2
    LABEL1:
        xor    eax, eax
    LABEL2:



【反復実行】

　.REPEAT〜.UNTIL/.UNTILCXZ、.WHILE〜.ENDW 文はブロックを反復実行します。
　これらは、C 言語の do、while 文と同様です。（但し .UNTIL は脱出条件を記述することに注意してください）
　また .BREAK 文や .CONTINUE 文で処理ブロックを終了したり先頭に移動したり出来ます。これらには条件式を記述することも出来ます。

    .REPEAT
        add    eax, edx
        .BREAK .IF    CARRY?
        dec    ecx
    .UNTIL     ZERO?

　このような記述は、以下のようなコードを生成します。

    LABEL1:
        add    eax, edx
        jc     LABEL2
        dec    ecx
        jnz    LABEL1
    LABEL2:



-----
【MASM談義】 8. 関数

【Hello world】

　PROTO 文でプロトタイプ宣言を行い、PROC 文で関数を実装します。
　次のコードは "Hello world." を出力するプログラムです。（C 言語標準ライブラリとリンクすることで exe を生成できます）

    ; > ml /c sample.asm

    .386
    .MODEL  FLAT, C

    PBYTE   TYPEDEF  PTR BYTE
    printf  PROTO    NEAR C, :PBYTE, :VARARG

    .CONST

    szMsg   BYTE    "Hello world.", 0AH, 0

    .CODE

    main    PROC    NEAR C PUBLIC, argc:SDWORD, argv:PTR PBYTE

            INVOKE  printf, ADDR szMsg
            xor     eax, eax
            ret

    main    ENDP

    END


　因みに、コードやデータを16バイト境界にアライメントするために ALIGN 16 を指定したい場合にはセグメントを

    ConstSeg   SEGMENT   READONLY PARA FLAT 'CONST'
    ; ...
    ConstSeg   ENDS

等のように PARA 指定で記述します。


【関数の呼び出し】

　関数を呼び出す際には INVOKE ディレクティブを使用します。

    INVOKE  (関数), (引数), ...

　関数には、関数名や、関数ポインタを表す式を記述します。
　例えば

    INVOKE   printf, ADDR szMsg, num, 3

は、C 言語の

    printf( &szMsg, num, 3 ) ;

と同じです。（但し C 言語で szMsg が配列の場合には & 演算子は不要であることに注意してください）
　関数は定義されている呼び出し規約に従って呼び出されます。

　引数の ADDR 演算子は変数などのアドレスを lea 命令で取得して渡します（アドレス式）。この際 eax レジスタの値が破壊されるので注意が必要です。
（この例の場合、szMsg がグローバル変数であれば (OFFSET szMsg) と同じ意味になり、その場合には eax レジスタは破壊されません）
　また32ビットより小さいサイズのデータを引数に渡す場合にも eax レジスタが使用されるので注意が必要です。（この際、データの型に従って符号ビットの拡張が行われます）


【ローカル変数】

　関数で使用するローカル変数は、関数ブロックの冒頭に LOCAL 文で宣言することが出来ます。
　例えば

    main    PROC    NEAR
            LOCAL   data1:PTR SDWORD
            LOCAL   data2[16]:SDWORD
            LOCAL   daat3:DATA_TYPE

と言った記述は、C 言語の

    main()
    {
       int *       data1 ;
       int         data2[16] ;
       DATA_TYPE   data3 ;

と同じ意味になります。

　ローカル変数や関数の引数は、[ebp+xxxx] 形式に置き換えられます。
　例えば、

    mov   eax, data2[ecx*4]

と言う記述は

    mov   eax, [ebp + ecx*4 + xxxx]

の形式になることに注意が必要です。


【関数プロローグとエピローグ】

　PROC 文は、（必要であれば）関数のスタックフレームを生成し、ret 命令でスタックフレームを解放します。
　PROC に USES でレジスタリストを指定した場合には、レジスタの PUSH/POP も行われます。
　x86 の C 言語の呼び出し規約では ebx, esi, edi レジスタ（及び暗黙に esp, ebp レジスタ）の内容は破壊してはならないので、これらレジスタを使用する場合には、USES 指定しておかなければなりません。

　こう言った関数のプロローグコードとエピローグコードは、ユーザーがマクロで定義することも出来ます。
　プロローグ及びエピローグマクロの引数フォーマットは定められていて、標準的なプロローグは以下のようになります。

    MyPrologue   MACRO   procname, flag, parmbytes, localbytes, reglist, userparams
       LOCAL   @REG
          IF     (parmbytes) OR (localbytes)
              push   ebp
              mov    ebp, esp
          ENDIF
          IF     localbytes
              sub    esp, localbytes
          ENDIF
          FOR   @REG, reglist
              push   @REG
          ENDM
          EXITM   %(parmbytes)
       ENDM

　プロローグ及びエピローグコードのマクロは OPTION ディレクティブで設定することが出来、デフォルトのプロローグ及びエピローグを設定するには、

    OPTION   PROLOGUE:PROLOGUEDEF
    OPTION   EPILOGUE:EPILOGUEDEF

と記述します。（明示しない場合にはこの設定が使用されます）

　例えば

    func   PROC   NEAR STDCALL USES ebx esi edi, param:DWORD
       LOCAL   local1:DWORD, local2:DWORD

この関数のプロローグコードは

    push   ebp
    mov    ebp, esp
    sub    esp, 8      ; 2つのDWORDローカル変数
    push   ebx         ; レジスタの退避
    push   esi
    push   edi

となり、ret 命令を記述すると

    pop    edi         ; レジスタの復帰
    pop    esi
    pop    ebx
    leave
    ret    4           ; STDCALL 呼び出し規約で1つのDWORD引数

のようなコードが生成されます。



-----
【MASM談義】 補遺

【命令セット】
　Pentium Pro までの命令とMMX、SSE命令セットの生成を許可するには以下のディレクティブを記述します。

    .686
    .387
    .MMX
    .XMM

※実際には .686, .XMM の2行で大丈夫だと思います。


【インクルードファイル】
　C言語用のヘッダファイル（.h）をMASM用のインクルードファイル（.INC）に変換するには h2inc コマンドを使用します。
　VS .NET 2005 以降には h2inc は付属していないらしいので、それ以前のバージョンのものを探す必要があります。


【構造体アライメント】
　構造体をC言語との間で受け渡す場合にはアライメントに注意する必要があります。
　MASM で構造体のアライメントは

    DATA_TYPE   STRUCT   1
       ; ...
    DATA_TYPE   ENDS

のように STRUCT 文で指定できます。
　C 言語でのアライメントはコンパイラに依存します。
　MS-C++ の場合、

    #pragma    pack( push, __STRUCT_ALIGN__, 1 )
    struct { /* ... */ } ;
    #pragma    pack( pop, __STRUCT_ALIGN__ )

のように記述します。


【呼び出し規約】
　C言語からMASMの関数を呼び出す場合、またMASMからC言語の関数を呼び出す場合には呼び出し規約に注意する必要があります。
　通常、呼び出し規約にはC、またはSTDCALLを使うべきです。（MS-C++ で __cdecl（デフォルト）, __stdcall）
　引数のレジスタ渡しを行う場合には MS-C++ コンパイラ依存で __fastcall を使用できます。__fastcall は引数2つまでを ecx, edx レジスタで渡すことが出来ます。

    void __fastcall func( int a, int b, int d ) ;

　この関数の実装はMASMで以下のように記述します。

    func   PROC   NEAR STDCALL PUBLIC, d:SDWORD
               ; ecx <- a, edx <- b

　またクラスのメンバ関数は、（MS-C++では）this ポインタが ecx レジスタに渡されます。